Soundstep, daily ActionScript. » Archive for experiment

Posts Tagged “experiment”

01 11 2008

Extend a Singleton

Posted by: Romuald in experiments, tags: as3, class, experiment, flash, flex

For a special purpose I had to extend a Singleton, to make my system fully flexible. I found complicated solutions that wasn't fully working as intended.

To use PureMVC, you have to extend a Singleton (Facade), which is the entry point of the framework. This is working only if you don't use the Facade class (the super Singleton) before using the subclass, otherwise you get an error, as the super singleton has already been instantiated.

Well this might be a simple solution but not working in my case.

First of all, they are a lot of solutions to correctly "lock" a Singleton, because in AS3, private constructor doesn't exist. Some of them have turn around, that you can solve with a bit more code, but the solution I prefer is instantiate the Singleton out of the constructor and method:

Actionscript:

private static var _instance:Singleton = new Singleton();

So, if I use the super singleton with a Singleton.getInstance(), and then use the subclass with a SingletonExtended.getInstance(), this will throw an error as when the SingletonExtended is called, the Singleton is called as well and has already been instantiated.

The solution I found is compare the super class name with a static class name, basically you can't use the keyword "this" when you declare a variable, but using "super" will return the same result (well that's odd but it is what I saw):

Actionscript:

private static var _className:String = getQualifiedClassName(super);

And then compare it with the super classname in the Singleton constructor:

Actionscript:

if (_instance != null && getQualifiedSuperclassName(this) != _className) throw new Error

if I trace(_className + " - " + getQualifiedSuperclassName(this)) in the Singleton constructor:

- when I use the Singleton class, I get: "null - Object"
- when I use the SingletonExtended class, I get: "Singleton - Singleton", meaning the constructor has been called from a subclass.

Until now, it is working pretty well, I can use:

Actionscript:

Singleton.getInstance().singletonValue
SingletonExtended.getInstance().singletonValue
SingletonExtended.getInstance().singletonExtendedValue

But we're not completely done. We can access to our two Singleton... but wait, "two Singleton", is that possible?

In fact, it is completely possible and it is even a problem. Let's say I have a undefined value in Singleton, like:

Actionscript:

private var _myValueNotInitialized:String;

And then you have a public method that is setting a value to this variable:

Actionscript:

public function initializeMyValue():void {
_myValueNotInitialized = "I am initialized";
}

You can now use:

Actionscript:

Singleton.getInstance().initializeMyValue();
or
SingletonExtended.getInstance().initializeMyValue();

But here is the problem: you still have 2 instances. One in Singleton and the other in SingletonExtended. If you use:
Singleton.getInstance().initializeMyValue();
and trace:
SingletonExtended.getInstance().myValueNotInitialized
you will get null, which is normal.

This doesn't make a lot of sense for a Singleton, does it?

The solution I found is updating the Singleton instance with the SingletonExtended one.

In the Singleton, I'm now able to update the instance:

Actionscript:

public function updateInstance(instance:Singleton):void {
if (instance != null && instance is Singleton) _instance = instance;
else throw new Error("Incorrect Singleton update");
}

And in the subclass SingletonExtended, I change the getInstance method:

Actionscript:

public static function getInstance():SingletonExtended {
Singleton.getInstance().updateInstance(_instance);
return _instance;
}

This is doing the job I needed, a fully Extended Singleton with no errors accessing the super or he subclass.

I tried to break it, but if it is possible, I didn't find the hole. And if you have a better solution, I'd be very happy to see it.

You can download the source by clicking here, or see the classes below.

The main class:

Actionscript:

package {
import flash.display.Sprite;
/**
* <b>Author:</b> Romuald Quantin - <a href="http://www.soundstep.com/" target="_blank">www.soundstep.com</a><br />
* <b>Class version:</b> 1.0<br />
* <b>Actionscript version:</b> 3.0<br />
* <b>Date:</b> 11-2008<br />
*/
public class Main extends Sprite {
//------------------------------------
// private properties
//------------------------------------
//------------------------------------
// public properties
//------------------------------------
//------------------------------------
// constructor
//------------------------------------
public function Main() {
trace("--- public properties ---");
trace(Singleton.getInstance().singletonValue + ">>> from Singleton");
trace(SingletonExtended.getInstance().singletonValue + ">>> from SingletonExtended");
trace(SingletonExtended.getInstance().singletonExtendedValue + ">>> from SingletonExtended");
trace(Singleton.getInstance().singletonValue + ">>> from Singleton");
trace("--- access to public methods ---");
trace(Singleton.getInstance().publicSingletonMethod() + ">>> from Singleton");
trace(SingletonExtended.getInstance().publicSingletonMethod() + ">>> from SingletonExtended");
trace(SingletonExtended.getInstance().publicSingletonExtendedMethod() + ">>> from SingletonExtended");
trace("--- access to private methods ---");
trace(Singleton.getInstance().accessPrivateSingletonMethod() + ">>> from Singleton");
trace(SingletonExtended.getInstance().accessPrivateSingletonMethod() + ">>> from SingletonExtended");
trace(SingletonExtended.getInstance().accessPrivateSingletonExtendedMethod() + ">>> from SingletonExtended");
trace("--- access to protected and overriden methods ---");
trace(Singleton.getInstance().accessProtectedSingletonMethod() + ">>> from Singleton");
trace(SingletonExtended.getInstance().accessProtectedSingletonMethod() + ">>> from SingletonExtended");
trace(SingletonExtended.getInstance().accessOverridenSingletonExtendedMethod() + ">>> from SingletonExtended");
trace("--- value not initialized ---");
trace("before = ", Singleton.getInstance().myValueNotInitialized);
Singleton.getInstance().initializeMyValue(); // or SingletonExtended.getInstance().initializeMyValue();
trace("after = ", Singleton.getInstance().myValueNotInitialized);
// this will generate errors
// as you can't instantiate twice a Singleton or a sublass of Singleton
//var s1:Singleton = new Singleton();
//var s2:SingletonExtended = new SingletonExtended();
}
//
// PRIVATE, PROTECTED
//________________________________________________________________________________________________
//
// PUBLIC
//________________________________________________________________________________________________
}
}

The Singleton class:

Actionscript:

package {
import flash.utils.getQualifiedClassName;
import flash.utils.getQualifiedSuperclassName;
/**
* <b>Author:</b> Romuald Quantin - <a href="http://www.soundstep.com/" target="_blank">www.soundstep.com</a><br />
* <b>Class version:</b> 1.0<br />
* <b>Actionscript version:</b> 3.0<br />
* <b>Date:</b> 11-2008<br />
*/
public class Singleton {
//------------------------------------
// private properties
//------------------------------------
private static var _instance:Singleton = new Singleton();
private static var _className:String = getQualifiedClassName(super);
private var _myValueNotInitialized:String;
//------------------------------------
// public properties
//------------------------------------
public var singletonValue:String = "Singleton value";
//------------------------------------
// constructor
//------------------------------------
public function Singleton() {
if (_instance != null && getQualifiedSuperclassName(this) != _className) throw new Error("Singleton is obviously... Singleton.");
}
//
// PRIVATE, PROTECTED
//________________________________________________________________________________________________
private function privateSingletonMethod():String {
return "privateSingletonMethod";
}
protected function protectedSingletonMethod():String {
return "protectedSingletonMethod";
}
//
// PUBLIC
//________________________________________________________________________________________________
public function initializeMyValue():void {
_myValueNotInitialized = "I am initialized";
}
public function updateInstance(instance:Singleton):void {
if (instance != null && instance is Singleton) _instance = instance;
else throw new Error("Incorrect Singleton update");
}
public static function getInstance():Singleton {
return _instance;
}
public function publicSingletonMethod():String {
return "publicSingletonMethod value";
}
public function accessPrivateSingletonMethod():String {
return privateSingletonMethod();
}
public function accessProtectedSingletonMethod():String {
return protectedSingletonMethod();
}
public function get myValueNotInitialized():String {
return _myValueNotInitialized;
}
}
}

The SingletonExtended class:

Actionscript:

package {
/**
* <b>Author:</b> Romuald Quantin - <a href="http://www.soundstep.com/" target="_blank">www.soundstep.com</a><br />
* <b>Class version:</b> 1.0<br />
* <b>Actionscript version:</b> 3.0<br />
* <b>Date:</b> 11-2008<br />
*/
public class SingletonExtended extends Singleton {
//------------------------------------
// private properties
//------------------------------------
private static var _instance:SingletonExtended = new SingletonExtended();
//------------------------------------
// public properties
//------------------------------------
public var singletonExtendedValue:String = "SingletonExtended value";
//------------------------------------
// constructor
//------------------------------------
public function SingletonExtended() {
if (_instance != null) throw new Error("SingletonExtended is obviously also... Singleton.");
}
//
// PRIVATE, PROTECTED
//________________________________________________________________________________________________
private function privateSingletonExtendedMethod():String {
return "privateSingletonExtendedMethod";
}
override protected function protectedSingletonMethod():String {
return "protectedSingletonMethod overriden in SingletonExtended, value in super.protectedSingletonMethod(): " + super.protectedSingletonMethod();
}
//
// PUBLIC
//________________________________________________________________________________________________
public static function getInstance():SingletonExtended {
Singleton.getInstance().updateInstance(_instance);
return _instance;
}
public function publicSingletonExtendedMethod():String {
return "publicSingletonExtendedMethod value";
}
public function accessPrivateSingletonExtendedMethod():String {
return privateSingletonExtendedMethod();
}
public function accessOverridenSingletonExtendedMethod():String {
return protectedSingletonMethod();
}
}
}

09 09 2008

Tween Scroll movement

Posted by: Romuald in experiments, tags: as3, experiment, flash

The ScrollPane component is a nice tool to use if you need to scroll a content or a list with more than text.

If you like to have everything a bit "tweened" in the sites you developed, you will feel the scroll movement of the scrollpane a bit straightforward.

There is an easy way to get this done.

When the user is scrolling the content with the scrollbar of the ScrollPane, the component dispatch an event:

ScrollEvent.SCROLL

The idea is to stop the movement of the content when this event is dispatched using:

e.stopImmediatePropagation()

And then handle the scrolling using a tweener.

I made an simple example with the CanvasUI class I built as it is using a ScrollPane component for the content, but you can use this code for a normal ScrollPane instance.

Here is the demo and the source, code of the main class below for a quick look.

Actionscript:

package {
import flash.display.Sprite;
import fl.events.ScrollEvent;
import fl.containers.ScrollPane;
import fl.controls.ScrollBarDirection;
import gs.TweenMax;
import com.soundstep.ui.layouts.*;
import com.soundstep.ui.*;
/**
* <b>Author:</b> Romuald Quantin - <a href="http://www.soundstep.com/" target="_blank">www.soundstep.com</a><br />
* <b>Actionscript version:</b> 3.0<br />
*/
public class Main extends Sprite {
//------------------------------------
// private properties
//------------------------------------
private var _canvas:CanvasUI;
//------------------------------------
// public properties
//------------------------------------
//------------------------------------
// constructor
//------------------------------------
public function Main() {
_canvas = new CanvasUI();
addChild(_canvas);
_canvas.canvasAlpha = .2;
_canvas.horizontalCenter = 0;
_canvas.verticalCenter = 0;
_canvas.width = 300;
_canvas.height = 300;
_canvas.addChildUI(new ContentText());
_canvas.refresh();
_canvas.scrollPane.addEventListener(ScrollEvent.SCROLL, scrollHandler, true);
}
//
// PRIVATE, PROTECTED, INTERNAL
//________________________________________________________________________________________________
private function scrollHandler(e:ScrollEvent):void {
e.stopImmediatePropagation();
switch (e.direction) {
case ScrollBarDirection.HORIZONTAL:
TweenMax.to(_canvas.scrollPane.content, .5, {x:e.position*-1});
break;
case ScrollBarDirection.VERTICAL:
TweenMax.to(_canvas.scrollPane.content, .5, {y:e.position*-1});
break;
}
}
// PUBLIC
//________________________________________________________________________________________________
}
}

23 06 2008

Flash liquid layout with BaseUI version 2

Posted by: Romuald in BaseUI, tags: as3, BaseUI, class, experiment, flash, flex, liquid layout, liquid UI

I've been working on the second version of BaseUI, so I'm happy to release it today.

THIS IS NOT AN UPDATE.

This new version is quite different, as well as the syntax, so the code you have written for the previous version won't work with this one.

I didn't try it yet in a real project but you shouldn't find too much bugs, comment if you find some, I'll solve them.

I've been working a lot with Flex and everyone enjoy a lot the layouts I think. I build this new version taking a lot of features from Flex. In the demo I use the Flex Builder interface to set the properties on a DisplayObject, so it is working pretty much the same.

I didn't build the Flex layouts obviously, but I'm thinking about it. Anyway, BaseUI allows you to use those following properties on a DisplayObject:

x, y, left, right, top, bottom, width, height, horizontalCenter, verticalCenter, ratio, alignX, alignY

You'll discover some nice features, for example you can use Number or String to set the properties. I've done that because you can now use percentage value for the width and the height!

This will make you able to do a lot more things, have a try in the demo.

Here is some examples of the new syntax:

Actionscript:

var baseUI:BaseUI = new BaseUI(this);
var element:ElementUI = baseUI.add(mySprite);
element.right = 10;
element.bottom = "10";
element.width = "50%"
element.height = 200;
addChild(mySprite);

Actionscript:

var baseUI:BaseUI = new BaseUI(this);